spring-boot/spring-boot-tests/spring-boot-smoke-tests/spring-boot-smoke-test-session/build.gradle

plugins {
	id 'java'
	id 'org.springframework.boot.conventions'
}

description = 'Spring Boot Session smoke test'

def sessionStores = [
	'hazelcast': [
		'com.hazelcast:hazelcast',
		'org.springframework.session:spring-session-hazelcast'		
	],
	'jdbc': [
		project(':spring-boot-project:spring-boot-starters:spring-boot-starter-jdbc'),
		'org.springframework.session:spring-session-jdbc'		,
		'com.h2database:h2'
	],
	'mongodb': [
		project(':spring-boot-project:spring-boot-starters:spring-boot-starter-data-mongodb'),
		'org.springframework.session:spring-session-data-mongodb'		
	],
	'redis': [
		project(':spring-boot-project:spring-boot-starters:spring-boot-starter-data-redis'),
		'org.springframework.session:spring-session-data-redis'		
	]
]

dependencies {
	implementation project(':spring-boot-project:spring-boot-starters:spring-boot-starter-actuator')
	implementation project(':spring-boot-project:spring-boot-starters:spring-boot-starter-security')
	implementation project(':spring-boot-project:spring-boot-starters:spring-boot-starter-web')
	
	sessionStores[project.findProperty('sessionStore') ?: 'jdbc'].each { runtimeOnly it }
	
	testImplementation project(':spring-boot-project:spring-boot-starters:spring-boot-starter-test')
}