spring-boot/spring-boot-samples/spring-boot-sample-actuator/build.gradle

buildscript {
	ext {
		springBootVersion = '1.5.2.BUILD-SNAPSHOT'
	}
	repositories {
		// NOTE: You should declare only repositories that you need here
		mavenLocal()
		mavenCentral()
		maven { url "http://repo.spring.io/release" }
		maven { url "http://repo.spring.io/milestone" }
		maven { url "http://repo.spring.io/snapshot" }
	}
	dependencies {
		classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")
	}
}

apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'idea'
apply plugin: 'org.springframework.boot'

jar {
	baseName = 'spring-boot-sample-actuator'
}

group = 'org.springframework.boot'
version = springBootVersion

repositories {
	// NOTE: You should declare only repositories that you need here
	mavenLocal()
	mavenCentral()
	maven { url "http://repo.spring.io/release" }
	maven { url "http://repo.spring.io/milestone" }
	maven { url "http://repo.spring.io/snapshot" }
}

dependencies {
	configurations {
		insecure.exclude module: 'spring-boot-starter-security'
	}

	compile("org.springframework.boot:spring-boot-starter-actuator")
	compile("org.springframework.boot:spring-boot-starter-jdbc")
	compile("org.springframework.boot:spring-boot-starter-security")
	compile("org.springframework.boot:spring-boot-starter-web")
	runtime("com.h2database:h2")

	compileOnly('org.springframework.boot:spring-boot-configuration-processor')

	testCompile("org.springframework.boot:spring-boot-starter-test")

	insecure configurations.runtime
}

// Slightly odd requirement (package a jar file as an insecure app, excluding Spring Security)
// just to demonstrate the "customConfiguration" feature of the Boot gradle plugin.
springBoot {
	customConfiguration = "insecure"
}

task wrapper(type: Wrapper) {
	gradleVersion = '1.6'
}

springBoot {
	buildInfo()
}